Texts Property, read only of ASPForm class

Property, read only | Member of  ScriptUtils.ASPForm | Changes | Purchase | Download

Description

Collection of all fields except files in the source document.

Syntax

Set vTexts = ASPForm.Texts

Returns

FormFields - Contains collection of document fields of files.

Examples

Upload - Enumerate text fields in a form.

<%
'Sample file Form-Texts.asp
' Enumerates all text (non-file) source fields.
'

'Create upload form
Dim Form: Set Form = Server.CreateObject("ScriptUtils.ASPForm")

'was the Form successfully received?
If Form.State = 0 Then
  'Number of text fields 
  Response.Write "<br>n of text fields:" & Form.Texts.Count
  '
  Response.Write "<br>" & vbCrLf

  Response.Write "Text field names and length:"
  'Enumerate texts 
  Dim Field: For Each Field In Form.Texts
    '
    Response.Write "<br> " & Field.Name & " - " & Field.Length
  Next

End If'Form.State = 0 then

%>  
<br>sample For <A Href=http://www.motobit.com>HugeASP upload</A>
<br>Enumerates all text (non-file) source fields.

<form name="file_upload" method="POST" ENCTYPE="multipart/form-data" >
File1:<input Name=SourceFile1 Type=File><br>
File2:<input Name=SourceFile2 Type=File><br>
Description:<input Name=Description1><br>
<input Type=CheckBox Name=Save>Also save<br>
<TextArea Name=LongText Cols=60 Rows=10></TextArea><br>
<input Type=HIDDEN Name=HIDDENField Value="Some hidden data">
<input Name=SubmitButton Value="Submit >>" Type=Submit><br>

</Form>

Upload - Save extra upload info to a database

<%
'Sample file Field-SaveAs.asp 
'Store extra upload info to a database
' and file contents to the disk

'Create upload form
Dim Form: Set Form = Server.CreateObject("ScriptUtils.ASPForm")

'was the Form successfully received?
If Form.State = 0 Then

  'Create destination path+filename for the source file.
  Dim DestinationPath, DestinationFileName
  DestinationPath = Server.MapPath(".") & "\"
  DestinationFileName = "~upload-" & Form("SourceFile").FileName


  'Open recordset to store uploaded data
  Dim RS: Set RS = OpenUploadRS

  'Store extra info about upload to database
  RS.AddNew
   RS("UploadDT") = Now()
   RS("Description") = Form.Texts("Description")
   RS("SourceFileName") = DestinationFileName
   '...
  RS.Update

  'Save file to the destination
  Form("SourceFile").SaveAs DestinationPath & DestinationFileName
  '

  Response.Write "<br>Source file names:"
  Dim Field: For Each Field In Form
    Response.Write "<br> " & Field.FileName
  Next
End If'Form.State = 0 then

Function OpenUploadRS()
  Dim RS  : Set RS = CreateObject("ADODB.Recordset")

  'Open dynamic recordset, table Upload
  RS.Open "Upload", GetConnection, 2, 2
  
  Set OpenUploadRS = RS
End Function 

Function GetConnection()
  Dim Conn: Set Conn = CreateObject("ADODB.Connection")
  Conn.Provider = "Microsoft.Jet.OLEDB.4.0"
  Conn.Open "Data Source=" & Server.MapPath("upload.mdb") 
	Set GetConnection = Conn
End Function



%>  
<br>sample For <A Href=http://www.motobit.com>HugeASP upload</A>
<br>Store extra upload info To a database
<br> And file contents To the disk
<form name="file_upload" method="POST" ENCTYPE="multipart/form-data">
File1:<input Name=SourceFile Type=File><br>
Description:<input Name=Description><br>
<input Name=SubmitButton Value="Submit >>" Type=Submit><br>
</Form>

See also

ASPForm.Items, ASPForm.Files

Other links for Texts

Methods of ASPForm class

AddConnection, CancelConnection, CheckRequirements, Read, Sleep, StringToBinary

Properties of ASPForm class

BytesRead, Files, FormType, getForm, CharSet, ChunkReadSize, Items, MaxMemoryStorage, NewUploadID, ReadTime, ReadTimeout, SizeLimit, SourceData, State, TempPath, Texts, ThreadPriority, TotalBytes, UploadID

ScriptUtils.ASPForm

The ASPForm collection retrieves the values of form elements posted to ASP script by a form using the POST method. ASPForm can process multipart/form-data or application/x-www-form-urlencoded data with length up to 2GB.

ScriptUtils

Huge ASP upload is easy to use, hi-performance ASP file upload component with progress bar indicator. This component lets you upload multiple files with size up to 4GB to a disk or a database along with another form fields. Huge ASP file upload is a most featured upload component on a market with competitive price and a great performance . The software has also a free version of asp upload with progress, called Pure asp upload , written in plain VBS, without components (so you do not need to install anything on server). This installation package contains also ScriptUtilities library. Script Utilities lets you create hi-performance log files , works with binary data , you can download multiple files with zip/arj compression, work with INI files and much more with the ASP utility.

© 1996 - 2011 Antonin Foller, Motobit Software | About, Contacts | e-mail: info@pstruh.cz


Other Motobit links:   IISTracer, real-time IIS monitor   ASP file upload - upload files to ASP. 
ActiveX/VBSScript registry editor  ActiveX NT User account manager  Export MDB/DBF from ASP Active LogFile  Email export  ActiveX/ASP Scripting Dictionary object